Re: [問題] hspice模擬inverter求Vih Vil
※ 引述《Dusuren ()》之銘言:
: 小弟最近開始接觸hspice軟體 在模擬inverter中
: 不知道是不是有指令可以直接求出 Vih Vil
: 還是只能一點一點慢慢找出斜率等於-1那點 冏
: 謝謝
* VIL, VIH, VOL, VOH, NMH, NML measurement
.global gnd vdd
.option post brief runlvl=5
.option nomod acct post=1 nopage
.option scale=1e-6
****Library model,simplified circuit and node initial file******
.prot
.lib './XXXX.l(自己的lib檔)' TT
.unprot
************************************
vvdd vdd 0 vcc
vgnd gnd 0 0
.param vcc=3.0v
.temp 25
************************************
.subckt inv Y A lp=0.35 wp=0.3 ln=0.3 wn=0.3
MN0 Y A gnd gnd NL w=wn l=ln
MP0 vdd A Y vdd PL w=wp l=lp
.ends inv
x1 2 1 inv wp=2.12 wn=0.82
x2 4 3 inv wp=2.12 wn=0.82
vx 3 1 0.01
vin 1 0 dc 0
*********************************************************************
.DC vin 0 3 0.01
***********************************************************************^
***********底下是求斜率等於負一(依書上Vil與Vih定義)
.measure dc voh find v(2) at 0
.measure dc vol find v(2) at 3
.measure dc vil find v(1) when par '(v(4)-v(2))/0.01'=-1 cross=1
.measure dc vih find v(1) when par '(v(4)-v(2))/0.01'=-1 cross=2
.measure dc NMH param='voh-vih'
.measure dc NML param='vil-vol'
*****底下是另一種求法,直接用hspcie裡的微分參數DERIV()~
.MEASURE DC VIL1 FIND V(1) WHEN DERIV('V(2)')=-1 cross=1
.MEASURE DC VIH1 FIND V(1) WHEN DERIV('V(2)')=-1 cross=2
.MEASURE DC VOHU FIND V(2) WHEN DERIV('V(2)')=-1 cross=1
.MEASURE DC VOLU FIND V(2) WHEN DERIV('V(2)')=-1 cross=2
.measure dc NML1 param='VIL1-VOLU'
.measure dc NMH1 param='VOHU-VIH'
.end
底下附上兩種sim出來的結果,好像略有差異。
個人覺得第二種的NML與NMH比較符合書上的定義。
都給你參考,因為要考慮NMOS是是depltion or enhancement load
.TITLE '* vil, vih, vol, voh, nmh, nml measurement'
voh=3.0
vol=0
vil=1.1226
vih=1.6526
nmh=1.3474
nml=1.1226
vohu=2.7774
volu=0.1932
vil1=1.1326
vih1=1.6626
nml1=0.9394
nmh1=1.1248
--
在臺灣,何謂R&D工程師?
1.Reverse and Decap :IC反相工程,去膠,打開封裝,拍照,複製電路佈局。
2.Resign and Die :沒死的就操到辭職,沒辭職的就操到死。
3.Rework and Debug :計畫永遠跟不上變化,變化永遠跟不上老闆的一句話!
4.Relax and Delay :太過於輕鬆(Relax),那麼就會Random Death (隨時陣亡)
但是外派到大陸的臺灣郎,晚上是R (鴨)陪客戶,白天是D (豬)任人宰割!
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 203.66.222.12
推
03/21 22:05, , 1F
03/21 22:05, 1F
→
03/21 22:45, , 2F
03/21 22:45, 2F
推
03/22 00:27, , 3F
03/22 00:27, 3F
討論串 (同標題文章)
本文引述了以下文章的的內容:
完整討論串 (本文為第 2 之 2 篇):